Team Switch – Modification

CSLover · 23.10.2025

Hi!

If possible, I’d like to ask for some help with the following plugin.

The plugin’s purpose is to automatically swap the teams after a predefined number of rounds.

However, the problem is that it doesn’t swap the team scores along with the teams.

Could someone help me fix this please?

XploitiT · 23.10.2025

В конце раунда:

Код:

g_TScore = get_member_game(m_iNumTerroristWins);
g_CTScore = get_member_game(m_iNumCTWins);

При swap:

Код:

set_member_game(m_iNumTerroristWins, g_CTScore);
set_member_game(m_iNumCTWins, g_TScore);

CSLover · 23.10.2025

Can you help me @XploitiT ?

Could you modify the plugin please?

XploitiT · 24.10.2025

@CSLover,

Код:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>
#include <reapi>

#define PLUGIN "Auto-Team swap"
#define VERSION "1.1 (Safe)"
#define AUTHOR ".sρiηX҉."

#define MAX_USER_INFO_LENGTH 256
#define TASKID 5007

#define VOTE_ACCESS ADMIN_CFG

#define rg_get_current_round() (get_member_game(m_iTotalRoundsPlayed) + 1)

new vote_count[2]
new pfTime, pMrounds, pRestart, g_TScore, g_CTScore;
new bool:TERR[MAX_PLAYERS + 1], bool:AFK[MAX_PLAYERS + 1]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_logevent("@OnRoundStart", 2, "1=Round_Start")
    register_logevent("@OnRoundEnd", 2, "1=Round_End")
    register_concmd("swap_vote", "cmdVote", VOTE_ACCESS, ": Vote for autoswapping teams")

    pfTime = register_cvar("amx_hud_time", "5.0")
    pMrounds = register_cvar("amx_max_rounds", "15")
    pRestart = get_cvar_pointer("sv_restartround")

    register_menucmd(register_menuid("Autoswap teams?"), (1 << 0) | (1 << 1), "voteTeamSwitch")
}

@OnRoundStart()
{
    if (rg_get_current_round() >= get_pcvar_num(pMrounds))
    {
        g_TScore = get_member_game(m_iNumTerroristWins);
        g_CTScore = get_member_game(m_iNumCTWins);
    }
}

@OnRoundEnd()
{
    if (get_pcvar_num(pfTime))
        @hud_task()
}

@hud_task()
{
    if (!get_pcvar_num(pRestart) && get_gametime() > get_pcvar_float(pfTime) * 2.0)
        if (!task_exists(TASKID))
            set_task(get_pcvar_float(pfTime) / 4, "@New_Hud", TASKID)
}

@New_Hud()
{
    new switch_sound[64]
    // HUD üzenet módosítva: középre vízszintesen, legfelül függőlegesen
    set_dhudmessage(100, 255, 0, -1.0, 0.0, 1, get_pcvar_float(pfTime) / 4, get_pcvar_float(pfTime))

    if (rg_get_current_round() >= get_pcvar_num(pMrounds))
    {
        show_dhudmessage(0, "Swap teams")

        for (new player = 1; player <= MAX_PLAYERS; player++)
        {
            // --- SAFE FILTER ---
            if (!is_user_connected(player))
                continue
            if (is_user_hltv(player))
                continue
            if (is_user_bot(player) && get_user_team(player) == 3)
                continue
            // -------------------

            AFK[player] = false

            if (get_user_team(player) == 1)
                TERR[player] = true
            else if (get_user_team(player) == 2)
                TERR[player] = false
            else
            {
                AFK[player] = true
                continue
            }

            // Remove VIP status if any
            if (cs_get_user_vip(player))
                cs_set_user_vip(player, 0, 0, 0)

            // Only active players get swapped
            if (!AFK[player])
            {
                cs_set_user_team(player, TERR[player] ? CS_TEAM_CT : CS_TEAM_T, CS_DONTCHANGE, false)

                // Respawn fix for VIPs
                if (cs_get_user_vip(player))
                {
                    cs_set_user_vip(player, 0, 0, 0)
                    ExecuteHamB(Ham_CS_RoundRespawn, player)
                    set_pcvar_num(pRestart, 1)
                }

                new iNum = random_num(1, 5)
                formatex(switch_sound, charsmax(switch_sound), "spk sound/hostage/hos%i.wav", iNum)

                switch (random_num(0, 1))
                {
                    case 0: client_cmd(player, "%s", switch_sound)
                    case 1: client_cmd(player, "spk ^"team switch^"")
                }
            }
        }

        set_member_game(m_iNumTerroristWins, g_CTScore);
        set_member_game(m_iNumCTWins, g_TScore);
    }
    else
    {
        new switch_time[16]
        new bottom_line = get_pcvar_num(pMrounds) - rg_get_current_round()
        num_to_word(bottom_line, switch_time, charsmax(switch_time))
        //client_cmd(0, "spk ^"%s round until switch^"", switch_time)
        show_dhudmessage(0, " %i ", bottom_line)
    }
}

public cmdVote(id, level, cid)
{
    if (!cmd_access(id, level, cid, 1) || task_exists(3517))
        return PLUGIN_HANDLED

    new keys = (1 << 0 | 1 << 1)
    for (new i = 0; i < 2; i++)
        vote_count[i] = 0

    new menu[MAX_USER_INFO_LENGTH]
    new len = format(menu, charsmax(menu), "[AMX] %s Autoswap teams?^n", get_pcvar_float(pfTime) ? "Disable" : "Enable")
    len += format(menu[len], charsmax(menu), "^n1. Yes")
    len += format(menu[len], charsmax(menu), "^n2. No")

    show_menu(0, keys, menu, 10)
    set_task(10.0, "vote_results", 3517)
    return PLUGIN_HANDLED
}

public voteTeamSwitch(id, key)
{
    vote_count[key]++
}

public vote_results()
{
    if (vote_count[0] > vote_count[1])
    {
        client_print(0, print_chat, "[%s %s] Voting success (yes ^"%d^") (no ^"%d^") %s is now %s",
            PLUGIN, VERSION, vote_count[0], vote_count[1], PLUGIN, get_pcvar_float(pfTime) ? "disabled" : "enabled")

        set_pcvar_float(pfTime, get_pcvar_float(pfTime) ? 0.0 : 5.0)
    }
    else
    {
        client_print(0, print_chat, "[%s %s] Voting failed (yes ^"%d^") (no ^"%d^")",
            PLUGIN, VERSION, vote_count[0], vote_count[1])
    }
}

Сообщение автоматически объединено: 24.10.2025

Test it

CSLover · 24.10.2025

@XploitiT
Thank you very very much!
It works!

Team Switch – Modification

CSLover

XploitiT

CSLover

XploitiT

CSLover

Кто просматривает тему