Spawn in the wall - de_tuscan32

CSLover · 24.10.2025

Last night we played on the de_tuscan32 map, which I downloaded from here , and when the situation reached 9v9, 1 or 2 players occasionally spawned inside a wall. After that, the server crashed.

I checked the spawn points and everything seemed fine.

What could be the problem?

XploitiT · 24.10.2025

Tap

Сообщение автоматически объединено: 24.10.2025

fix spawns

Tigs · 25.10.2025

Use this, dont need download maps with 32 spawns.
Only use default maps

https://forums.alliedmods.net/showpost.php?p=2767109&postcount=1

Shaurman · 25.10.2025

А может просто побольше добавить спавнов, зач качать другую карту? Просто в энт файле добавить и не надо людям карту качать ещё раз. Через bspguy, например.

Сообщение автоматически объединено: 25.10.2025

Спавн на голову выше и урона не будет от падения, плюс шансов появиться в стене - меньше

hlds · 26.10.2025

BSPEDIT.exe для редактирования + gsm-loader для определения координат.

mlibre · 03.11.2025

Нет необходимости скачивать ещё один BSP с дополнительными точками появления; это можно сделать с помощью дополнения, не изменяя оригинальную карту. Это касается всех.

CSLover · 03.11.2025

@mlibre Please include the solution in your reply as well.

mlibre · 03.11.2025

Конечно, я считаю это ошибкой новичка, которую люди продолжают совершать спустя годы. Я всё ещё вижу карты вроде cs_assault32, de_train32, de_nuke32... и так далее. Помимо якобы исправления спавнов, это добавляет новую нагрузку в файл fastdl. Но, в любом случае, давайте перейдём к главному. Вот плагин, которым я тогда пользовался, и он исправляет проблему.

Я немного изменил его, удалив ненужные мне части, и заставив его запускаться напрямую, без cvar.

Код:

#include <amxmodx>
#include <engine>

#define PLUGIN    "Fail Spawns Protector"
#define VERSION    "1.2e"
#define AUTHOR    "zmd94 & mlibre"

#define PlayerNotMove 1994

new bool:g_bServerReload

new g_sEntFile[256]
new g_iNowTerrorSpawnNum, g_iNowCTSpawnNum
new g_iMaxSpawn = 16

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)

    SpawnPointCount()
}

public plugin_precache()
{
    get_localinfo("amxx_configsdir", g_sEntFile, charsmax(g_sEntFile))
    
    new szMapName[32]; get_mapname(szMapName, charsmax(szMapName))
    
    formatex(g_sEntFile, charsmax(g_sEntFile), "%s/fw_file", g_sEntFile)
    
    if( !dir_exists(g_sEntFile) )
    {
        mkdir(g_sEntFile)
        
        formatex(g_sEntFile, charsmax(g_sEntFile), "%s/%s.ini", g_sEntFile, szMapName)
        
        return
    }
    
    formatex(g_sEntFile, charsmax(g_sEntFile), "%s/%s.ini", g_sEntFile, szMapName)
    
    server_print("[Fail Spawn Protector] Creating new file")
    
    new iFile = fopen(g_sEntFile, "rt")
    
    if( !iFile )
        return
        
    new Ent, Var, NewSpawnEnt
    new szData[256]
    new PlayerTeam[10], RequiredSpawnEnt[10], SpawnLimit[10], SaveOrigin[3][10], SaveAngles[3][10]
    new Float:Origin[3], Float:Angles[3]
    
    while(fgets(iFile, szData, charsmax(szData)))
    {
        trim(szData)
        
        if( !szData[0] || szData[0] == ';' || (szData[0] == '/' && szData[1] == '/') )
            continue
            
        parse(szData,
        PlayerTeam, charsmax(PlayerTeam),
        SpawnLimit, charsmax(SpawnLimit),
        RequiredSpawnEnt, charsmax(RequiredSpawnEnt),
        SaveOrigin[0], 9,
        SaveOrigin[1], 9,
        SaveOrigin[2], 9,
        SaveAngles[0], 9,
        SaveAngles[1], 9,
        SaveAngles[2], 9)
        
        NewSpawnEnt = str_to_num(RequiredSpawnEnt)
        
        Origin[0] = str_to_float(SaveOrigin[0])
        Origin[1] = str_to_float(SaveOrigin[1])
        Origin[2] = str_to_float(SaveOrigin[2])
        
        Angles[0] = str_to_float(SaveAngles[0])
        Angles[1] = str_to_float(SaveAngles[1])
        Angles[2] = str_to_float(SaveAngles[2])
        
        for(Var = 1; Var <= NewSpawnEnt; Var++)
        {
            switch(PlayerTeam[0])
            {
                case 'T':
                {
                    Ent = create_entity("info_player_deathmatch")
                }
                case 'C':
                {
                    Ent = create_entity("info_player_start")
                }
            }
            
            entity_set_origin(Ent, Origin)
            
            entity_set_vector(Ent, EV_VEC_angles ,Angles)
            
            DispatchSpawn(Ent)
        }
    }
    
    fclose(iFile)
    
    server_print("[Fail Spawn Protector] Deleting old file")
    
    delete_file(g_sEntFile)
}

public SpawnPointCount()
{
    new iFile = fopen(g_sEntFile, "a+")
    
    if( !iFile )
        return
        
    new Target = -1
    new TerrorEnts, CTEnts
    new RequiredSpawnEnt
    
    new bool:Found
    new szData[256], PlayerTeam[32]
    new Float:EntityOrigin[3], Float:EntityAngles[3]
    
    while((Target = find_ent_by_class(Target, "info_player_deathmatch")))
    {
        if(is_valid_ent(Target))
        {
            TerrorEnts = TerrorEnts + 1
            
            if( !Found )
            {
                entity_get_vector(Target, EV_VEC_origin, EntityOrigin)
                
                entity_get_vector(Target, EV_VEC_angles, EntityAngles)
                
                Found = true
            }
        }
    }
    
    if(TerrorEnts != g_iMaxSpawn)
    {
        if(TerrorEnts < g_iMaxSpawn)
        {
            RequiredSpawnEnt = g_iMaxSpawn - TerrorEnts
            
            server_print("[Fail Spawn Protector] Required %d + Terro spawn ent!", RequiredSpawnEnt)
            
            g_bServerReload = true
        }
        
        PlayerTeam = "T"
        
        formatex(szData, charsmax(szData), "%s %d %d %.1f %.1f %.1f %.1f %.1f %.1f^n", PlayerTeam, 0, RequiredSpawnEnt, EntityOrigin[0], EntityOrigin[1], EntityOrigin[2], 0, EntityAngles[1], 0)
        
        fputs(iFile, szData)
        
        server_print("[Fail Spawn Protector] Auto reload TT")
    }
    
    Found = false
    
    while((Target = find_ent_by_class(Target, "info_player_start")))
    {
        if(is_valid_ent(Target))
        {
            CTEnts = CTEnts + 1
            
            if( !Found )
            {
                entity_get_vector(Target, EV_VEC_origin, EntityOrigin)
                
                entity_get_vector(Target, EV_VEC_angles, EntityAngles)
                
                Found = true
            }
        }
    }
    
    if(CTEnts != g_iMaxSpawn)
    {
        if(CTEnts < g_iMaxSpawn)
        {
            RequiredSpawnEnt = g_iMaxSpawn - CTEnts
            
            server_print("Required %d + CT spawn ent!", RequiredSpawnEnt)
            
            g_bServerReload = true
        }
        
        PlayerTeam = "CT"
        
        formatex(szData, charsmax(szData), "%s %d %d %.1f %.1f %.1f %.1f %.1f %.1f^n", PlayerTeam, 0, RequiredSpawnEnt, EntityOrigin[0], EntityOrigin[1], EntityOrigin[2], 0, EntityAngles[1], 0)
        
        fputs(iFile, szData)
        
        server_print("[Fail Spawn Protector] Auto reload CT")
    }
    
    fclose(iFile)
    
    g_iNowTerrorSpawnNum = TerrorEnts
    
    g_iNowCTSpawnNum = CTEnts
    
    server_print("[Fail Spawn Protector] CS Spawn Entity: %d || Terror Spawn Entity: %d", g_iNowCTSpawnNum, g_iNowTerrorSpawnNum)
    
    if(g_bServerReload)
    {
        server_print("[Fail Spawn Protector] Server is reloading")
        
        // Reload server?
        set_task(0.5, "delay_restart")
    }
}

public delay_restart()
{
    server_cmd("restart")
}

официальная тема

CSLover · 03.11.2025

@mlibre
Thank you very much.
I’m now using the regular de_tuscan map instead of de_tuscan32, and I’ve done the same with all the other maps as well.
If the problem occurs again, I’ll use what you sent me.

mlibre · 03.11.2025

Хорошо, перефразируя вашу проблему, причину сбоя сервера, хочу уточнить, что, по моему мнению, это не связано с BSP, поэтому мы имеем дело с двумя разными проблемами. Мы уже описали первое решение.

ufame · 05.11.2025

@CSLover, use https://github.com/UnrealKaraulov/newbspguy for edit spawn points coords (XYZ) without any plugins.

mlibre · 05.11.2025

Этот инструмент, безусловно, является альтернативой, если вы не используете amxmodx. Ещё один важный момент: после «модификации» карты её не нужно переименовывать; вы всё равно допустите ту же ошибку, что и с nuke32... cpl_mil_32. Проблем не возникнет, если название останется прежним.

ufame · 06.11.2025

@mlibre @CSLover

С помощью bspguy редактируется список ентити передаваемый сервером. Так-же есть функционал в rehlds - просто передавать отредактированный файл со списком ентити клиентам от сервера не изменяя саму карту.
Перекачивать же карту есть смысл только при редактировании самой карты путем декомпиляции и перекомпиляции со своими изменениями.

Самый простой и относительно понятный вариант - использовать встроенные возможности ReHLDS:

GitHub - rehlds/ReHLDS: Enhanced version of the HLDS engine with bug fixes, security patches, and optimizations for stable servers.

Enhanced version of the HLDS engine with bug fixes, security patches, and optimizations for stable servers. - rehlds/ReHLDS

github.com

Квар с документацией:

sv_use_entity_file // Use custom entity file for a map. Path to an entity file will be "maps/[map name].ent". 0 - use original entities. 1 - use .ent files from maps directory. 2 - use .ent files from maps directory and create new .ent file if not exist.

Shaurman · 06.11.2025

Может нужен гайд по пользованию bspguy?

wood-grouse · 06.11.2025

Releases · wootguy/bspguy

Edit GoldSrc maps without decompiling. Contribute to wootguy/bspguy development by creating an account on GitHub.

github.com

Spawn in the wall - de_tuscan32

CSLover

Вложения

XploitiT

Вложения

Tigs

Shaurman

hlds

mlibre

CSLover

mlibre

CSLover

mlibre

ufame

mlibre

ufame

GitHub - rehlds/ReHLDS: Enhanced version of the HLDS engine with bug fixes, security patches, and optimizations for stable servers.

Shaurman

wood-grouse

Releases · wootguy/bspguy

Кто просматривает тему