Получить гранату при убийстве

[Mizer]

Не могу найти плагин, убиваешь тебе даётся граната.

 

[dendying]

квар в game.cfg ReGameDLL.

 

[dreamxleo]

квар в game.cfg ReGameDLL.

Я думаю, он имел ввиду экипировку при убийстве, а не дроп гранаты.

 

[Albertio]

не тестил

#include <amxmodx>
#include <reapi>

// [ru] Количество наградных HE(осколочная) гранат. 0 - не награждать.
// [en] The number of award-winning HE(high explosive) grenades. 0 - not awarded.
#define AWARD_IS_HE 1

// [ru] Количество наградных FB(светошумовая) гранат. 0 - не награждать.
// [en] The number of award-winning FB(flash) grenades. 0 - not awarded.
#define AWARD_IS_FB 1

// [ru] Количество наградных SG(дымовая) гранат. 0 - не награждать.
// [en] The number of award-winning SG(smoke) grenades. 0 - not awarded.
#define AWARD_IS_SG 1

public plugin_init() {
    register_plugin("Award Grenade", "1.0.0", "Albertio");

    RegisterHookChain(RG_CBasePlayer_Killed, "Player_Killed_Post", true);
}

public Player_Killed_Post(const victimId, killerId) {
    if(victimId == killerId)
        return;
  
    if(!is_user_alive(killerId))
        return;

    #if AWARD_IS_HE > 0
        GivePlayerGrenade(killerId, WEAPON_HEGRENADE, "weapon_hegrenade", AWARD_IS_HE);
    #endif

    #if AWARD_IS_FB > 0
        GivePlayerGrenade(killerId, WEAPON_FLASHBANG, "weapon_flashbang", AWARD_IS_FB);
    #endif

    #if AWARD_IS_SG > 0
        GivePlayerGrenade(killerId, WEAPON_SMOKEGRENADE, "weapon_smokegrenade", AWARD_IS_SG);
    #endif
}

stock GivePlayerGrenade(
    const playerId,
    const WeaponIdType:grenadeType,
    const grenadeName[] = "",
    const grenadeNum
) {
    new grenadeId;
    new grenadeBPAmmo = rg_get_user_bpammo(playerId, grenadeType);

    if(grenadeBPAmmo == 0) {
        grenadeId = rg_give_item(playerId, grenadeName);

        if(grenadeNum == 1)
            return;
    } else {
        grenadeId = rg_find_weapon_bpack_by_name(playerId, grenadeName);
    }

    if(!is_nullent(grenadeId))
        rg_set_user_bpammo(playerId, grenadeType, grenadeBPAmmo + grenadeNum);
}