Weaponbox Models for HLDM 0.4

/* AMX Mod X
*   Weaponbox Models for HLDM
*
* http://aghl.ru/forum/ - Russian Half-Life and Adrenaline Gamer Community
*
* This file is provided as is (no warranties)
*/

#include <amxmodx>
#include <fakemeta_util>
#include <hamsandwich>

#define PLUGIN "Weaponbox Models for HLDM"
#define VERSION "0.4"
#define AUTHOR "KORD_12.7"

#define IsPlayer(%1)  (1 <= %1 <= g_MaxPlayers)

#define HLW_DISPLACER    20
#define HLW_KNIFE    25

new 
g_CvarEnable,
g_CvarRendEnable,
g_CvarRendColor, 
g_CvarRendMode,
g_MaxPlayers,
g_XV11382,
g_RGB[3]

new const g_wpn_models[][] = 
{
    "models/w_weaponbox.mdl",
    "models/w_crowbar.mdl",
    "models/w_9mmhandgun.mdl",
    "models/w_357.mdl",
    "models/w_9mmAR.mdl",
    "models/w_weaponbox.mdl",
    "models/w_crossbow.mdl",
    "models/w_shotgun.mdl",
    "models/w_rpg.mdl",
    "models/w_gauss.mdl",
    "models/w_egon.mdl",
    "models/w_hgun.mdl",
    "models/w_grenade.mdl",
    "models/v_tripmine.mdl",
    "models/w_satchel.mdl",
    "models/w_sqknest.mdl",
    "models/w_bgrap.mdl",
    "models/w_desert_eagle.mdl",
    "models/w_pipe_wrench.mdl",
    "models/w_saw.mdl",
    "models/w_displacer.mdl",
    "models/w_weaponbox.mdl",
    "models/w_shock_rifle.mdl",
    "models/w_spore_launcher.mdl",
    "models/w_m40a1.mdl",
    "models/w_knife.mdl"
}

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_cvar("wpnbox_version", VERSION, FCVAR_SPONLY | FCVAR_SERVER | FCVAR_UNLOGGED)
    
    RegisterHam(Ham_Spawn, "weaponbox", "fw_WpnboxSpawnPost", 1)
    
    g_CvarEnable = register_cvar("wpnbox_models", "1")
    g_CvarRendEnable = register_cvar("wpnbox_render", "1")
    g_CvarRendColor = register_cvar("wpnbox_render_color", "random")
    
    g_MaxPlayers = get_maxplayers()
}

public plugin_cfg()
{
    new color[32]
    get_pcvar_string(g_CvarRendColor, color, charsmax(color))
    trim(color)
    
    if (equali(color, "random"))
        g_CvarRendMode = 0
    else
    {
        new r[4], g[4], b[4]
        parse(color, r, charsmax(r), g, charsmax(g), b, charsmax(b))
        
        g_RGB[0] = str_to_num(r)
        g_RGB[1] = str_to_num(g)
        g_RGB[2] = str_to_num(b)
        
        g_CvarRendMode = 1
    }
    
    if (get_cvar_pointer("displacer_version"))
        g_XV11382 = 1
}

public fw_WpnboxSpawnPost(ent)
{
    if (get_pcvar_num(g_CvarEnable) && pev_valid(ent))
    {
        new id = pev(ent, pev_owner)
        
        if (IsPlayer(id))
        {
            new wpn_id = get_user_weapon(id)
            
            if (g_XV11382 && wpn_id == HLW_EGON)
                wpn_id = HLW_DISPLACER
            
            if (HLW_CROWBAR <= wpn_id <= HLW_KNIFE)
            {
                engfunc(EngFunc_SetModel, ent, g_wpn_models[wpn_id])
    
                if (wpn_id == HLW_TRIPMINE)
                {
                    set_pev(ent, pev_body, 3)
                    set_pev(ent, pev_sequence, 8)
                }
                
                if (get_pcvar_num(g_CvarRendEnable))
                {
                    switch(g_CvarRendMode)
                    {
                        case 1: fm_set_rendering(ent, kRenderFxGlowShell, g_RGB[0], g_RGB[1], g_RGB[2], kRenderNormal, 16)
                        case 0: fm_set_rendering(ent, kRenderFxGlowShell, random_num(1, 255), random_num(1, 255), random_num(1, 255), kRenderNormal, 16)
                    }
                }
            }
        }
    }
    
    return HAM_IGNORED
}

#include <amxmodx>

#define PLUGIN "Weaponlist for weaponboxes" 
#define VERSION "1.0"         
#define AUTHOR "Glaster"

public plugin_init() {             
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_clcmd("wlist","wlist");
}   
                  
public wlist(id){
    for (new i=1; i<31;i++){ 
        new name[32];
        get_weaponname(i, name, 31 );
        console_print(id,name,"",i);         
    }                                                                           
}